blob: f320d987505d492316517ad835f1b9ea0962d419 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Art Gramlich <art@gramlich-net.com>
pkgname=icu74
pkgver=74.2
pkgrel=1
pkgdesc="International Components for Unicode library"
arch=(x86_64)
url="https://icu.unicode.org"
license=('LicenseRef-Unicode-3.0'
'BSD-2-Clause'
'BSD-3-Clause')
depends=('gcc-libs' 'glibc' 'sh')
makedepends=('python')
provides=(libicu{data,i18n,io,test,tu,uc}.so)
source=(icu-74.2.tar.gz::https://github.com/unicode-org/icu/archive/refs/tags/release-74-2.tar.gz
ICU-22132.patch
LICENSE)
# https://github.com/unicode-org/icu/releases/download/release-74-2/SHASUM512.txt
sha512sums=('728ae0f09ffc802d675bcf5b849e3081472de8417736bf8b7df0f4db9d1fb8073779be76536764c9111f7cb0e5ab2d2af6c644cc24be432b9eeae9063802ad6c'
'1178062ccfcf7ecc698c64132b3612e73f9c4b0bbfaa668ae2039f3eb4cb2722d0b08a9f45b057da10def7a308d5c8d14c0c644892e7f11092c9cc488c850ab7'
'c1c3b2deaf2aeb1d90c1ca85d57db921e140e5087c1eba579dabaca94568a840a0e105145b8016f3b7269216ddc1b0ac56e1d5d1753129a99367e51e2080a6b0')
#validpgpkeys=('BA90283A60D67BA0DD910A893932080F4FB419E3') # "Steven R. Loomis (filfla-signing) <srloomis@us.ibm.com>"
#validpgpkeys+=('9731166CD8E23A83BEE7C6D3ACA5DBE1FD8FABF1') # "Steven R. Loomis (ICU Project) <srl@icu-project.org>"
#validpgpkeys+=('FFA9129A180D765B7A5BEA1C9B432B27D1BA20D7') # "Fredrik Roubert <fredrik@roubert.name>"
#validpgpkeys+=('E4098B78AFC94394F3F49AA903996C7C83F12F11') # "keybase.io/srl295 <srl295@keybase.io>"
#validpgpkeys+=('4569BBC09DA846FC91CBD21CE1BBA44593CF2AE0') # "Steven R. Loomis (codesign-qormi) <srloomis@us.ibm.com>"
#validpgpkeys=('0E51E7F06EF719FBD072782A5F56E5AFA63CCD33') #"Craig Cornelius (For use with ICU releases) <ccornelius@google.com>"
validpgpkeys=('3DA35301A7C330257B8755754058F67406EAA6AB') # Craig Cornelius <ccornelius@google.com>
prepare() {
cd icu-release-74-2/icu4c/source
# Required fix for thunderbird 115 to show Calendar and sidebar properly
# https://bugzilla.mozilla.org/show_bug.cgi?id=1843007
# https://unicode-org.atlassian.net/browse/ICU-22132
patch -Np1 < "${srcdir}/ICU-22132.patch"
}
build() {
cd icu-release-74-2/icu4c/source
./configure --prefix=/usr \
--sysconfdir=/etc \
--mandir=/usr/share/man \
--sbindir=/usr/bin
make
}
check() {
cd icu-release-74-2/icu4c/source
make -k check || true
}
package() {
cd icu-release-74-2/icu4c/source
make -j1 DESTDIR="${pkgdir}" install
# we keep only the libraries
rm -rf "${pkgdir}/usr/bin"
rm -rf "${pkgdir}/usr/include"
rm -rf "${pkgdir}/usr/lib/pkgconfig"
rm -rf "${pkgdir}/usr/lib/icu"
rm -rf "${pkgdir}/usr/lib/"*.so
rm -rf "${pkgdir}/usr/share"
# Install license
install -Dm644 "${srcdir}/LICENSE" "${pkgdir}"/usr/share/licenses/icu74/LICENSE
}
groups+=(build-shims)
|