blob: 49e4da25dc112372a63d51fd387a07abcbf5ee0d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: BlackEagle <ike.devolder@gmail.com>
# Contributor: Dany Martineau <dany.luc.martineau@gmail.com>
pkgname=clementine
pkgver=1.4.0rc1
pkgrel=3
pkgdesc='A modern music player and library organizer'
url=https://www.clementine-player.org/
license=(GPL)
arch=(x86_64 i486 i686 pentium4)
depends=(chromaprint gst-plugins-base-libs libcdio libgpod liblastfm-qt5 libmtp libmygpo-qt5
taglib protobuf qt5-x11extras projectm alsa-lib libpulse crypto++ hicolor-icon-theme)
makedepends=(boost cmake qt5-tools sparsehash)
optdepends=(
'gst-plugins-base: "Base" plugin libraries'
'gst-plugins-good: "Good" plugin libraries'
'gst-plugins-bad: "Bad" plugin libraries'
'gst-plugins-ugly: "Ugly" plugin libraries'
'gst-libav: Libav plugin'
'gvfs: Various devices support'
)
source=("https://github.com/clementine-player/Clementine/releases/download/${pkgver//+/-}/$pkgname-${pkgver//+/-}.tar.xz")
sha256sums=('96ba2f5f3ece47b2c1065e980dcc37ada93ea42cf37b794ee804514ce4a65459')
prepare() {
sed -e 's|CRYPTOPP cryptopp|CRYPTOPP libcryptopp|' -i $pkgname-${pkgver//+/-}/CMakeLists.txt # Fix crypto++ detection
}
build() {
cmake -B build -S $pkgname-${pkgver//+/-} \
-DCMAKE_INSTALL_PREFIX=/usr \
-DUSE_SYSTEM_PROJECTM=ON \
-DUSE_SYSTEM_TAGLIB=ON
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
# disable -Werror
eval "$(
declare -f build | \
sed '
s|cmake -B build |cmake -B build -DBUILD_WERROR=OFF |
'
)"
# RC1 misses includes to QPainterPath
source+=('clementine-1.4.0rc1-qpainterpath-missing-include.patch')
sha256sums+=('64d538336a4f017abf1c6efa0973fc95eb1ac44aaf510b7c1e8a041113e1cdfd')
eval "$(
declare -f prepare \
| sed '
$ i cd $pkgname-$pkgver
$ i patch -Np1 -i "$srcdir"/clementine-1.4.0rc1-qpainterpath-missing-include.patch
'
)"
|