# Maintainer

pkgbase=python-bootstrap
pkgname=(python-build python-installer python-tomli python-pep517 python-setuptools python-flit-core python-wheel python-typing_extensions python-packaging python-setuptools-scm python-jaraco.functools python-calver)
pkgver=0.5
pkgrel=2
arch=(any)
license=('custom')
makedepends=(python git)
url="https://gitlab.archlinux.org/archlinux/python-bootstrap"
# From archlinux-contrib
# package/parse-submodules https://github.com/jelly/python-bootstrap.git
source=(
  "${pkgbase}::git+https://github.com/tatokis/python-bootstrap.git#branch=3.11"
  "${pkgbase}-build::git+https://github.com/pypa/build.git"
  "${pkgbase}-flit::git+https://github.com/takluyver/flit.git"
  "${pkgbase}-installer::git+https://github.com/pypa/installer.git"
  "${pkgbase}-pep517::git+https://github.com/pypa/pep517.git"
  "${pkgbase}-setuptools::git+https://github.com/pypa/setuptools.git"
  "${pkgbase}-tomli::git+https://github.com/hukkin/tomli.git"
  "${pkgbase}-wheel::git+https://github.com/pypa/wheel.git"
  "${pkgbase}-typing_extensions::git+https://github.com/python/typing_extensions.git"
  "${pkgbase}-packaging::git+https://github.com/pypa/packaging.git"
  "${pkgbase}-setuptools-scm::git+https://github.com/pypa/setuptools_scm.git"
  "${pkgbase}-jaraco.functools::git+https://github.com/jaraco/jaraco.functools.git"
  "${pkgbase}-calver::git+https://github.com/di/calver.git"
)
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP')

prepare() {
  cd python-bootstrap
  git submodule init

  git config submodule."external/build".url "${srcdir}/${pkgbase}"-build
  git config submodule."external/flit".url "${srcdir}/${pkgbase}"-flit
  git config submodule."external/installer".url "${srcdir}/${pkgbase}"-installer
  git config submodule."external/pep517".url "${srcdir}/${pkgbase}"-pep517
  git config submodule."external/setuptools".url "${srcdir}/${pkgbase}"-setuptools
  git config submodule."external/tomli".url "${srcdir}/${pkgbase}"-tomli
  git config submodule."external/wheel".url "${srcdir}/${pkgbase}"-wheel
  git config submodule."external/typing_extensions".url "${srcdir}/${pkgbase}"-typing_extensions
  git config submodule."external/packaging".url "${srcdir}/${pkgbase}"-packaging
  git config submodule."external/setuptools_scm".url "${srcdir}/${pkgbase}"-setuptools-scm
  git config submodule."external/jaraco.functools".url "${srcdir}/${pkgbase}"-jaraco.functools
  git config submodule."external/calver".url "${srcdir}/${pkgbase}"-calver

  git -c protocol.file.allow=always submodule update
  git submodule update --init --recursive
}


build() {
  cd python-bootstrap
  python -m bootstrap.build
}

package_python-build() {
  depends=(python-pep517 python python-packaging)
  pkgdesc="A simple, correct PEP 517 build frontend"
  cd python-bootstrap
  python -m bootstrap.install dist/build-*-py3-none-any.whl -d $pkgdir
}

package_python-installer() {
  depends=(python-pep517 python)
  pkgdesc="Low-level library for installing a Python package from a wheel distribution"
  cd python-bootstrap
  python -m bootstrap.install dist/installer-*-py3-none-any.whl -d $pkgdir
}

package_python-flit-core() {
  depends=(python-pep517 python)
  pkgdesc="Simplified packaging of Python modules (core backend)"
  cd python-bootstrap
  python -m bootstrap.install dist/flit_core-*-py3-none-any.whl -d $pkgdir
}

package_python-pep517() {
  pkgdesc="Wrappers to build Python packages using PEP 517 hooks"
  depends=(python)
  cd python-bootstrap
  python -m bootstrap.install dist/pep517-*-py3-none-any.whl -d $pkgdir
}

package_python-setuptools() {
  pkgdesc="Easily download, build, install, upgrade, and uninstall Python packages"
  depends=(python python-jaraco.functools)
  cd python-bootstrap
  python -m bootstrap.install dist/setuptools-*-py3-none-any.whl -d $pkgdir
}

package_python-tomli() {
  pkgdesc="A lil' TOML parser"
  depends=(python)
  cd python-bootstrap
  python -m bootstrap.install dist/tomli-*-py3-none-any.whl -d $pkgdir
}

package_python-wheel() {
  pkgdesc="A built-package format for Python"
  depends=(python python-packaging)
  cd python-bootstrap
  python -m bootstrap.install dist/wheel-*-py2.py3-none-any.whl -d $pkgdir
}

package_python-setuptools-scm() {
  pkgdesc="Handles managing your python package versions in scm metadata"
  depends=(python python-packaging python-setuptools python-typing_extensions)
  cd python-bootstrap
  python -m bootstrap.install dist/setuptools_scm-*-py3-none-any.whl -d $pkgdir
}

package_python-typing_extensions() {
  pkgdesc="Backported and Experimental Type Hints for Python 3.8+"
  depends=(python)
  cd python-bootstrap
  python -m bootstrap.install dist/typing_extensions-*-py3-none-any.whl -d $pkgdir
}

package_python-packaging() {
  pkgdesc="Core utilities for Python packages"
  depends=(python)
  cd python-bootstrap
  python -m bootstrap.install dist/packaging-*-py3-none-any.whl -d $pkgdir
}

package_python-jaraco.functools() {
  pkgdesc="Functools like those found in stdlib"
  depends=(python python-more-itertools)
  cd python-bootstrap
  python -m bootstrap.install dist/jaraco.functools-*-py3-none-any.whl -d $pkgdir
}

package_python-calver() {
  pkgdesc="Setuptools extension for CalVer package versions"
  depends=(python)
  cd python-bootstrap
  python -m bootstrap.install dist/calver-*-py3-none-any.whl -d $pkgdir
}