From 6331f93eefe97d2237388b53fd1b6fa8d4be9fce Mon Sep 17 00:00:00 2001
From: Tasos Sahanidis <tasos@tasossah.com>
Date: Sun, 12 May 2024 05:42:46 +0300
Subject: extra/python-pendulum: Downgrade to 2.1.2

---
 extra/python-pendulum/PKGBUILD | 51 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 extra/python-pendulum/PKGBUILD

diff --git a/extra/python-pendulum/PKGBUILD b/extra/python-pendulum/PKGBUILD
new file mode 100644
index 00000000..8651f2b0
--- /dev/null
+++ b/extra/python-pendulum/PKGBUILD
@@ -0,0 +1,51 @@
+# pendulum 3 doesn't build under 32 bit for now, so force 2.1.2
+# Maintainer: David Runge <dvzrv@archlinux.org>
+
+_name=pendulum
+pkgname=python-pendulum
+pkgver=2.1.2
+pkgrel=$((8+$pkgrel))
+pkgdesc="Python datetimes made easy"
+arch=(x86_64)
+url="https://pendulum.eustace.io/"
+license=(MIT)
+depends=(
+  python
+  python-dateutil
+  python-pytzdata
+)
+makedepends=(
+  python-build
+  python-installer
+  python-poetry-core
+  python-wheel
+  python-setuptools
+)
+checkdepends=(
+  python-babel
+  python-freezegun
+  python-pytest
+  python-pytz
+)
+source=($pkgname-$pkgver.tar.gz::https://github.com/sdispater/$_name/archive/$pkgver.tar.gz)
+sha512sums=('c367320ade0d10b7eb9c880286176161b925d7df052f7de85ddd169594bbe778776ea74df451f00186df98be3e32b7399c68ca4b40123e2c456206410e3a1ab2')
+b2sums=('c95cd131fc95a0d19ef11f180cc42126cb8a6ea3aaf4b3bbedbc5ce4c1b37a6624f2a1be92f1a6fd6b1f14f5d20fa5f32e8230f896ab7a216f02f00e85b98738')
+
+build() {
+  cd $_name-$pkgver
+  # NOTE: calling pyproject-build as we otherwise call the project's build.py script:
+  # https://github.com/sdispater/pendulum/issues/665
+  pyproject-build --wheel --no-isolation
+}
+
+check() {
+  cd $_name-$pkgver
+  pytest -vv
+}
+
+package() {
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 {CHANGELOG.md,README.rst} -t "$pkgdir/usr/share/doc/$pkgname/"
+  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+}
-- 
cgit v1.2.3-54-g00ecf